Emacs LSP 客户端，从 lsp-mode 迁移到 eglot

tree -L 3 ~/.emacs.d/cache/language-server/

(require 'eglot)

;; 定义启动命令和参数
(add-to-list 'eglot-server-programs
               `(java-mode "jdtls"
                           "-configuration" ,(expand-file-name "cache/language-server/java/jdtls/config_linux" user-emacs-directory)
                           "-data" ,(expand-file-name "cache/java-workspace" user-emacs-directory)
                           ,(concat "--jvm-arg=-javaagent:" (expand-file-name "~/.m2/repository/org/projectlombok/lombok/1.18.20/lombok-1.18.20.jar"))))

;; 服务端启动成功后，客户端需要传一些初始化参数给服务端，相关参数在各自的服务端github上面找
(cl-defmethod eglot-initialization-options ((server eglot-lsp-server) &context (major-mode java-mode))
  `(:settings
    (:java
     (:configuration
      (:runtime [(:name "JavaSE-1.8" :path "/usr/local/jdk-8")
                 (:name "JavaSE-11" :path "/usr/local/graalvm-ce-java11-22.0.0.2")
                 (:name "JavaSE-17" :path "/usr/local/graalvm-ce-java17-22.0.0.2" :default t)])
      :format (:settings (:url ,(expand-file-name (locate-user-emacs-file "cache/eclipse-java-google-style.xml"))
                               :profile "GoogleStyle"))
      ;; NOTE: https://github.com/redhat-developer/vscode-java/issues/406#issuecomment-356303715
      ;; > We enabled it by default so that workspace-wide errors can be reported (eg. removing a public method in one class would cause compilation errors in other files consuming that method).
      ;; for large workspaces, it may make sense to be able to disable autobuild if it negatively impacts performance.
      :autobuild (:enabled t)
      ;; https://github.com/dgileadi/vscode-java-decompiler
      :contentProvider (:preferred "fernflower")))
    ;; support non standard LSP `java/classFileContents', `Location' items that have a `jdt://...' uri
    ;; https://github.com/eclipse/eclipse.jdt.ls/issues/1384
    :extendedClientCapabilities (:classFileContentsSupport t)
    ;; bundles: decompilers, etc.
    ;; https://github.com/dgileadi/dg.jdt.ls.decompiler
    :bundles ,(let ((bundles-dir (expand-file-name (locate-user-emacs-file "cache/language-server/java/bundles" user-emacs-directory)))
                    jdtls-bundles)
                (->> (when (file-directory-p bundles-dir)
                       (directory-files bundles-dir t "\\.jar$"))
                     (append jdtls-bundles)
                     (apply #'vector)))))

;; https://github.com/joaotavora/eglot/discussions/888#discussioncomment-2386710
(cl-defmethod eglot-execute-command
  (_server (_cmd (eql java.apply.workspaceEdit)) arguments)
  "Eclipse JDT breaks spec and replies with edits as arguments."
  (mapc #'eglot--apply-workspace-edit arguments))

(cl-defgeneric +eglot/ext-uri-to-path (uri)
  "Support extension uri."
  nil)

;; https://github.com/eclipse/eclipse.jdt.ls/blob/b4e5cb4b693d5d503d90be89b0b9a8abe9db41a5/org.eclipse.jdt.ls.core/src/org/eclipse/jdt/ls/core/internal/JDTUtils.java#L809
(cl-defmethod +eglot/ext-uri-to-path (uri &context (major-mode java-mode))
  "Support Eclipse jdtls `jdt://' uri scheme."
  (when-let* ((jdt-scheme-p (string-prefix-p "jdt://" uri))
              (filename (save-match-data
                          (when (string-match "jdt://contents/\\(.*?\\)/\\(.*\\)\.class\\?" uri)
                            (format "%s.java"
                                    (replace-regexp-in-string "/" "." (match-string 2 uri) t t))))))
    (+eglot/create-source-file :java/classFileContents uri filename)))

;; https://github.com/emacs-lsp/lsp-mode/blob/d3bc47bde5ffc1bace40122a6ec0c6d8b9e84500/clients/lsp-clojure.el#L272
;; https://github.com/clojure-lsp/clojure-lsp/blob/master/lib/test/clojure_lsp/shared_test.clj
(cl-defmethod +eglot/ext-uri-to-path (uri &context (major-mode clojure-mode))
  "Support Clojure-lsp `zifile://', `jar:file://' uri scheme."
  (when-let* ((clj-scheme-p (or (string-prefix-p "jar:file://" uri)
                                (string-prefix-p "zipfile://" uri)))
              (filename (when (string-match "^\\(jar:file\\|zipfile\\)://.+\\(!/\\|::\\)\\(.+\\)" uri)
                          (let* ((ns-path (match-string 3 uri))
                                 (filename (replace-regexp-in-string "/" "." ns-path)))
                            filename))))
    (+eglot/create-source-file :clojure/dependencyContents uri filename)))

(defun +eglot/create-source-file (method uri filename)
  "Create source file and metadata in project root .eglot directory."
  (let* ((cache-dir (file-name-concat (project-root (eglot--current-project)) ".eglot"))
         (source-file (expand-file-name (file-name-concat cache-dir filename))))
    (unless (file-readable-p source-file)
      (let ((content (jsonrpc-request (eglot--current-server-or-lose) method (list :uri uri)))
            (metadata-file (+eglot/path-to-metadata-file source-file)))
        (unless (file-directory-p cache-dir) (make-directory cache-dir t))
        (with-temp-file source-file (insert content))
        (with-temp-file metadata-file (insert uri))))
    source-file))

(defun +eglot/path-to-metadata-file (path)
  (format "%s.%s.metadata" (file-name-directory path) (file-name-base path)))

(defun +eglot/path-to-ext-uri (path)
  "Retrieve extension uri from metadata."
  (let ((metadata-file (+eglot/path-to-metadata-file path)))
    (when (file-exists-p metadata-file)
      (with-temp-buffer
        (insert-file-contents metadata-file)
        (buffer-string)))))

(define-advice eglot--uri-to-path (:around (orig-fn uri) advice)
  "Support non standard LSP uri scheme."
  (when (keywordp uri) (setq uri (substring (symbol-name uri) 1)))
  (or (+eglot/ext-uri-to-path uri)
      (funcall orig-fn uri)))

(define-advice eglot--path-to-uri (:around (orig-fn path) advice)
  "Support non standard LSP uri scheme."
  (or (+eglot/path-to-ext-uri path)
      (funcall orig-fn path)))